taskkill /f /im OverwolfUpdater.exe /t
taskkill /f /im OverwolfStore.exe /t
taskkill /f /im Overwolf.exe /t
taskkill /f /im OverwolfHelper.exe /t
taskkill /f /im OverwolfHelper64.exe /t
taskkill /f /im OverwolfBrowser.exe /t
taskkill /f /im OverwolfLauncher.exe /t

rmdir "%LocalAppData%\Overwolf" /S /Q
rmdir "%ProgramData%\Overwolf" /S /Q
rmdir "%ProgramFiles(x86)%\Common Files\Overwolf" /S /Q

mklink /J "%LocalAppData%\Overwolf" "%~dp0ICafeCloud\LocalAppData"
mklink /J "%ProgramData%\Overwolf" "%~dp0ICafeCloud\ProgramData"
mklink /J "%ProgramFiles(x86)%\Common Files\Overwolf" "%~dp0ICafeCloud\ProgramFiles(x86)\Common Files"

Reg.exe add "HKLM\SOFTWARE\WOW6432Node\Overwolf" /v "InstallFolder" /t REG_SZ /d "%~dp0\" /f

setlocal EnableDelayedExpansion
set "tempfile=%TEMP%\maxver.txt"
del /f /q "%tempfile%" >nul 2>&1

:: runadmin
cd /d "%~dp0"
:: 获取最大版本目录名并写入临时文件
powershell -NoProfile -Command "Get-ChildItem -Directory -Name | Where-Object { $_ -like '0.*' } | Sort-Object { [version]($_ -replace '[^\d.]','') } -Descending | Select-Object -First 1 | Out-File -Encoding ASCII -FilePath '%tempfile%'"

set /p max_folder=<"%tempfile%"
del /f /q "%tempfile%" >nul 2>&1

if not defined max_folder (
    echo No folder starting with 0. found
    goto :eof
)

echo Keeping highest version folder: %max_folder%
echo.

:: 删除非最大版本文件夹
for /d %%f in (0.*) do (
    if /I not "%%f"=="%max_folder%" (
        echo Deleting: %%f
        rmdir /s /q "%%f"
    )
)

set "targetDir=ICafeCloud\ProgramFiles(x86)\Common Files"
for /d %%f in ("%targetDir%\0.*") do (
    if /I not "%%~nxf"=="%max_folder%" (
        echo Deleting: %%f
        rmdir /s /q "%%f"
    )
)
endlocal