REM WeGame Repo 安装脚本
cd /d %~dp0
cd ..
cd ..

REM 添加防火墙
netsh advfirewall firewall add rule name="WeGame" dir=in program="%cd%\wegame.exe" action=allow
netsh advfirewall firewall add rule name="WeGame tcls_core" dir=in program="%cd%\tcls\tcls_core.exe" action=allow
netsh advfirewall firewall add rule name="WeGame rail" dir=in program="%cd%\apps\Rail\rail.exe" action=allow

REM 拷贝文件
xcopy /S /I /Y "%cd%\config\*.info" "%cd%\config_backup"
xcopy /S /I /Y "%cd%\Data\json_db\*.local" "%cd%\Data\json_backup_tmp"
xcopy /S /I /Y "%cd%\Data\json_backup_tmp" "%cd%\Data\json_db\back_up"
rd /s /q "%cd%\Data\json_backup_tmp"

REM 安装驱动
xcopy /S /I /Y "%cd%\Data\driver\wegame\*.sys" "%windir%\Sysnative\drivers"

for /f "tokens=4-5 delims=[.XP " %%i in ('ver') do set VERSION=%%i.%%j
if "%version%" == "10.0" goto CopyNewDriver
if "%version%" == "6.3" goto CopyNewDriver
if "%version%" == "6.2" goto CopyNewDriver
if "%version%" == "6.1" goto CopyOldDriver
if "%version%" == "6.0" goto CopyOldDriver
if "%version%" == "5.2" goto CopyXPDriver
if "%version%" == "5.1" (goto CopyXPDriver) else (goto CopyNewDriver)

:CopyXPDriver
xcopy /S /I /Y "%cd%\Data\driver\common\*.sys" "%windir%\system32\drivers"
goto eof

:CopyOldDriver
xcopy /S /I /Y "%cd%\Data\driver\common\*.sys" "%windir%\Sysnative\drivers"
goto eof

:CopyNewDriver
xcopy /S /I /Y "%cd%\Data\driver\win10\*.sys" "%windir%\Sysnative\drivers"
goto eof

:eof
exit